scalar m = 1[kg];
scalar l = 0.5[m];
scalar h = 0.21[m];
scalar d = 0.3[m];
scalar alfa = 5 [deg];
scalar t = 2[ s ];
scalar c = 1 [N/m];
scalar g = 9.81 [ m/ s2 ];
point point1 = ( 0 [ m ], 0 [ m ], 0 [ m ] );
point point2 = ( d, 0 [ m ], 0 [ m ] );
point point3 = pointCyl( -90[deg]-alfa, l, 0 [ m ] );
point point4 = ( d, -l, 0 [ m ] );
point point5 = pointCyl( -90[deg]-alfa, h, 0 [ m ] );
point point6 = ( d, -h, 0 [ m ] );
vector vector1 = vectorPP( point1, point3 );
vector vector2 = vectorPP( point2, point4 );
solid solid1 = cylinder( point1, point3, 0.005 [ m ], mass = 0 [kg] );
solid solid2 = sphere( point3, 0.03 [ m ], mass = m );
solid solid3 = cylinder( point2, point4, 0.005 [ m ], mass = 0 [kg] );
solid solid4 = sphere( point4, 0.03 [ m ], mass = m );
body body1 = body(  );
body body2 = body( color = RGB( 0, 0, 255 ) );
body body3 = body( color = RGB( 0, 0, 255 ) );
joint joint1 = rotational( body1, body2, point1, projectZ );
joint joint2 = rotational( body1, body3, point2, projectZ );
force forse1 = spring( body2, point5, body3, point6, c );
gravity gravity1 = parallel( reverse( projectY ) );
sensor phi11 = angleVV( vector1, projectX );
sensor phi12 = angleVV( vector2, projectX );
sensor phi1 = -90[deg]+phi11;
sensor phi2 = -90[deg]+phi12;
sensor k1 = sqrt(g/l);
sensor k2 = sqrt(g/l+2*c*h*h/(m*l*l));
sensor phi1_th = alfa*cos((k1+k2)/2*time)*cos((k2-k1)/2*time);
sensor phi2_th = alfa*sin((k1+k2)/2*time)*sin((k2-k1)/2*time);
sensor phi1_delta = abs(phi1-phi1_th);
sensor phi2_delta = abs(phi2-phi2_th);
event event1 = reformsBySensor( list( stop(  ) ), time, t );

/\///////////////////////////////////////////////////////////////////////////////////
/\   Прикрепление объектов
body body2 < (solid1, solid2, point5, point3 );
body body3 < (solid3, solid4, point6, point4 );

/\///////////////////////////////////////////////////////////////////////////////////
/\   Инерциальное звено;
set ground = body1;

/\///////////////////////////////////////////////////////////////////////////////////
/\   Единицы измерения;
set units = SI;