/\///////////////////////////////////////////////////////////////////////////////////
/\   Пояснения к проекту
set remark=
"Расчет траектории материальной точки в плоскости OXY, движущейся под воздействием силы, направленной вдоль оси OX, с заданной начальной скоростью, направленной к оси OX под углом alpha.";
scalar m=1[ kg ];
scalar alpha=45[ deg ];
scalar b=100[ N/ s2 ];
scalar v0=5[m/s];
scalar r "радиус шара"=0.01[m];
point point_place=point( 0 [ m ], 0 [ m ], 0 [ m ], visible = hide: );
point point_sphere=point( 0 [ m ], 0 [ m ], 0 [ m ], visible = hide: );
solid solid_sphere=sphere( point_sphere, r, mass = m );
body body_place=body( color = RGB( 229, 229, 229 ), visible = hide: );
set ground = body_place;
body body_place < ( point_place );
color green=index( 44 );
body body_sphere=body( color = green );
body body_sphere < ( point_sphere, solid_sphere );
function functionF(t[s])     "Закон изменения силы"= b*#t*#t;
force force_sphere=force( body_sphere, point_sphere, projectX, functionF, list( time ) );
condition condition_sphere "Начальное значение скорости v0 для звена body_sphere"=transVelocity( body_place, vectorPP( point_place, point( 1 [ m ], 1 [ m ], 0 [ m ] ) ), body_sphere, point_sphere, v0 );
reform reform_stop=stop(  );
sensor sensor_coordy=bodyDisplacement( body_place, point_place, projectY, body_sphere, point_sphere );
sensor sensor_coordx=bodyDisplacement( body_place, point_place, projectX, body_sphere, point_sphere );
sensor coordx_Theoretical=b/(12*m)*(5[m]/(v0*sin(alpha)))*(5[m]/(v0*sin(alpha)))*(5[m]/(v0*sin(alpha)))*(5[m]/(v0*sin(alpha)))+5[m]/tg(alpha);
sensor coordx_delta=sensor_coordx-coordx_Theoretical;
event event_stop=reformsBySensor( list( reform_stop ), sensor_coordy, 5[ m ], gauge = list( coordx_delta, coordx_Theoretical, sensor_coordx, sensor_coordy ) );

/\///////////////////////////////////////////////////////////////////////////////////
/\   Единицы измерения;
set units = SI;