Приложение   Описание синтаксиса текстового представления
             диаграмм взаимодействия


<message sequence chart document> ::= 
       mscdocument <document head> <document body>
       endmscdocument <end>

<document head> ::=
       <msc document name> [ related to <sdl reference> ] <end>

<sdl reference> ::=
        <sdl document identifier>


<identifier> ::=
        [ <qualifier> ] <name>

<qualifier> ::=
        <path item> { / <path item> }*

<path item> ::=
        <scope unit class> <name>

<scope unit class> ::=   
        system
      | block
      | process

<document body> ::=
      { <message sequence chart> 
        | <submsc>
        | <msc diagram>
        | <submsc diagram> }*

---------------------------------------------------

<message sequence chart> ::=
      msc <msc head> <msc body> endmsc <end>

<msc head> ::=
      <message sequence chart name> <end> [ <msc interface> ]

<msc interface> ::=
      inst <instance list> <end>

<instance list> ::=
      <instance name> [ : <instance kind> ] [ , <instance list> ]

<instance kind> ::=
      [ <kind denominator> ] <kind name>

<kind denominator> ::=
      system | block | process | service

<msc body> ::=
      <msc section> *

<msc section> ::=
      [ <global condition> ] { <instance definition> }*

-------------------------------------------------------

<instance definition> ::=
      instance <instance head> <instance body> endinstance <end>

<instance head> ::=
      <instance name> [ : <instance kind> ] [ decomposed ] <end>

<instance body> ::=
      <instance event list> [ <stop> ]

<instance event list> ::=
      {  <message input> 
       | <message output>
       | <create>
       | <timer statement>
       | <coregion>
       | <action>
       | <condition> }*

--------------------------------------------------------

<message input> ::=
      in <msg identification> from <address> <end>

<message output> ::=
      out <msg identification> to <address> <end>

<msg identification> ::
      <message name> [ , <message instance name> ] [ ( <parameter list> ) ]

<parameter list> ::=
      <parametr name> [ , <parameter list> ]

<address> ::=
      <instance name> 
    | env

---------------------------------------------------------

<global condition> ::=
      condition <condition name> <end>

<condition> ::=
      condition <condition name> 
         [ shared { <shared instance list> | all } ] <end>

<shared instance list> ::=
     <instance name> [ , <shared instance list> ]

--------------------------------------------------------

<timer statement> ::=
      <set>
    | <reset>
    | <timeout>

<set> ::=
      set <timer name>  [ , <timer instance name> ] 
             [ ( <duration name> ) ] <end>

<reset> ::=
      reset <timer name> [ , <timer instance name> ] <end>

<timeout> ::=
      timeout <timer name> [ , <timer instance name> ] <end>

-------------------------------------------------------

<action> ::=
      action <action text> <end>

-------------------------------------------------------

<create> ::=
      create <instance name> [ ( <parameter list> ) ]

-------------------------------------------------------

<stop> ::=
          stop

------------------------------------------------------

<coregion> ::=
       concurrent { <message output>+ 
                  | <message input>+ }
       endconcurrent <end>

------------------------------------------------------

<submsc> ::=
        submsc <msc head> <msc body> endsubmsc <end>

-------------------------------------------------------

Лексика языка диаграмм взаимодействия

<lexical unit> ::=
          <word>
        | <character string>
        | <special>
        | <composite special>
        | <note>
        | <keyword>
        | <semicolon>

<keyword> ::=
          action
        | all
        | block
        | comment
        | concurrent
        | condition
        | create
        | decomposed
        | endconcurrent
        | endinstance
        | endmsc
        | endmscdocument
        | endsubmsc
        | env
        | from
        | inst
        | instance
        | msc
        | mscdocument
        | in
        | out
        | process
        | referenced
        | related to
        | reset
        | service
        | set
        | shared
        | stop
        | submsc
        | system
        | timeout
        | to
        
<text> ::=
        { <alphanumeric>
         | <other character>
         | <special>
         | <full stop>
         | <underline>
         | <space>
         | <apostrophe> } *

<special> ::=
           +
         | -
         | %
         | !
         | /
         | >
         | *
         | (
         | )
         | "
         | ,
         | =
         | :

<semicolon> ::=
          ;

--------------------------------------------

<note> ::=  
            /*  <text> */

<end> ::= 
            [ <comment> ] <semicolon>

<comment> ::=
            comment <character string>